@ECHO OFF
REM --------------------------------------------------------------------
REM
REM Batch file parameters:
REM %1 ... prefix of the input data files.
REM %2 ... maximum number MIND of big bricks within the whole
REM        computational volume.  It need not be specified.
REM %3 ... maximum number MGRID of small bricks in the Fresnel volume.
REM        It need not be specified.
REM For more details on MIND and MGRID see the description of main input
REM data in 'NETIND.FOR'.  If specified and non-zero, they overwrite the
REM default values in the program 'NETIND.FOR'.
REM
REM Input files required:
REM   %1GRI1.DAT, %1NET1.DAT, %1NET2.DAT,
REM   %1GRI3.DAT, %1NET3.DAT, %1NET4.DAT, and files referred from them.
REM First  3 files correspond to the first iteration,
REM latter 3 files correspond to all subsequent iterations.
REM Inside all these files %1NET.OUT, which will be created of %1NET.H,
REM has to be referred as the SEP parameter file describing the grid
REM dimensions and numerical parameters.
REM
REM After each network ray tracing from the 1st (source) point to the
REM 2nd (receiver) point, the PAUSE statement enables to terminate the
REM iterations.  Consecutive network ray tracing in the opposite
REM is not required during the last iteration (i.e. if the big bricks
REM cannot be made smaller).
REM
REM Output file TIME.OUT contains the times of starting and terminating
REM the individual programs.
REM
REM --------------------------------------------------------------------
  IF NOT EXIST GRID.EXE    GOTO :EXE
  IF NOT EXIST NET.EXE     GOTO :EXE
  IF NOT EXIST NETIND.EXE  GOTO :EXE
  IF NOT EXIST %1GRI1.DAT  GOTO :DAT
  IF NOT EXIST %1NET1.DAT  GOTO :DAT
  IF NOT EXIST %1NET2.DAT  GOTO :DAT
  IF NOT EXIST %1GRI3.DAT  GOTO :DAT
  IF NOT EXIST %1NET3.DAT  GOTO :DAT
  IF NOT EXIST %1NET4.DAT  GOTO :DAT
  IF NOT EXIST %1NET.H     GOTO :DAT
  COPY  %1NET.H %1NET.OUT >NUL
REM First iteration:
  ECHO.|TIME  >TIME.OUT
  ECHO GRID  >>TIME.OUT
  ECHO '%1GRI1.DAT' / |GRID
  ECHO.|TIME >>TIME.OUT
  ECHO NET 1 >>TIME.OUT
  ECHO '%1NET1.DAT' / |NET
  ECHO.|TIME >>TIME.OUT
  ECHO NET 2 >>TIME.OUT
  ECHO '%1NET2.DAT' / |NET
  ECHO.|TIME >>TIME.OUT
  ECHO NETIND>>TIME.OUT
  ECHO '%1NET1.DAT' '%1NET2.DAT' '%1NET3.DAT' %2 %3 / |NETIND
  ECHO.|TIME >>TIME.OUT
REM Next iterations:
:FV
  ECHO.|TIME >>TIME.OUT
  ECHO GRID  >>TIME.OUT
  ECHO '%1GRI3.DAT' / |GRID
  ECHO.|TIME >>TIME.OUT
  ECHO NET 3 >>TIME.OUT
  ECHO '%1NET3.DAT' / |NET
  ECHO.|TIME >>TIME.OUT
  ECHO PAUSE >>TIME.OUT
  ECHO If all iterations are completed, press Ctrl-C.
  PAUSE
  ECHO.|TIME >>TIME.OUT
  ECHO NET 4 >>TIME.OUT
  ECHO '%1NET4.DAT' / |NET
  ECHO.|TIME >>TIME.OUT
  ECHO NETIND>>TIME.OUT
  ECHO '%1NET3.DAT' '%1NET4.DAT' '%1NET3.DAT' %2 %3 / |NETIND
  ECHO.|TIME >>TIME.OUT
GOTO :FV
:EXE
  ECHO GRID.EXE, NET.EXE, and NETIND.EXE not in the current directory.
  GOTO :END
:DAT
  ECHO %1GRI1.DAT, %1NET1.DAT, %1NET2.DAT, %1GRI3.DAT, %1NET3.DAT,
  ECHO %1NET4.DAT and %1NET.H not in the current directory.
:END